POV-Ray:12-11

１２．１１　インテリア（interior）

インテリア(interior)とは、物体の内部の特性を表すもので、ガラスなどの屈折や簡易的な集光を表現することができる。旧バージョン互換のために屈折率の指定はfinishでもできるが、使用しないこと。

注意：このマニュアルでは、わかり良さのために、テクスチャ項目の１つとしてここに入れているが、インテリアはテクスチャと独立した存在であり、テクスチャ文の中に記述することはできない。マテリアル文を使用すると１つの定義にまとめることができる。　⇒「11.4-8　マテリアル（material）」

＜ interior の構文＞

interior{ [INTERIOR_IDENTIFIER] ior VALUE caustics VALUE dispersion VALUE dispersion_samples SAMPLES fade_distanse DISTANCE fade_power POWER fade_color COLOR }
interior	インテリアを宣言するキーワード
INTERIOR_IDENTIFIER	識別子の名前。（40文字以下）
ior　VALUE	屈折率の指定。 [デフォルト：1.0]（屈折なし）水1.33、ガラス1.5、ダイヤモンド2.4程度である。※ 標準インクルードファイルのconsts.incにいくつかの値が定義されている。　⇒「12.11-1　屈折」
caustics VALUE	透明物体の屈折により生じる集光を簡易的に表現する。通常０～１程度の値を指定する。値に反比例して集光部分の大きさが変化する。この効果は透明物体の影の範囲にしか生じない。[デフォルト：0.0]　⇒「12.11-2　集光（caustics）」　⇒正確な表現は「９．フォトンマッピング」
dispersion VALUE	透過光の分散（波長による屈折率の変化で起こる光の色分解）強度。適切な値は、1.01～1.1程度である。[デフォルト：1.0]　⇒「12.11-3　分散」
dispersion_samples SAMPLES	透過光の色分解のコントロール値。２以上の値で、大きな値ほど滑らかになる。[デフォルト：7]
fade_distanse DISTANCE	透過光が減衰する距離の指定。光の強度が1/2になる距離を指定する。[デフォルト：0.0]
fade_power POWER	透過光の減衰特性の指定。光がどれだけ早く減衰するかを指定する。現実的な値は1～2である。[デフォルト：0.0]
fade_color COLOR	透過光の減衰による着色。　[デフォルト：<0,0,0> ]

インテリアは透明な物体に有効な機能である。不透明な物体にはインテリアの設定は不必要である。

12.11-1　屈折（ior）

光が空間から透明な物体へ入ると、光の進行方向が変化する。このような変化は屈折と呼ばれている。光の屈折率は、物質の密度により決定される。空気、水、クリスタル、ダイヤモンドなどは、それぞれ異なった密度であるため、屈折率もそれぞれ異なる。インテリアでは、屈折を指定するためにior（屈折率）が使われる。

図12.11-1は屈折の指定による表面の違いを表している。

図12.11-1　屈折


●屈折の例（図12.11-1）



     sphere{0,1           // 左の球

       pigment{White*0.8 filter 1.0}

       interior{ ior 1.0}

       translate x*-1.2

     }



     sphere{0,1           // 右の球

       pigment{White*0.8 filter 1.0}

       interior{ ior 1.51}

       translate x*1.2

     }

12.11-2　集光（caustics）

集光とは、透明物体を透過するときにレンズ効果により集光される光のことである。水の入ったグラスに光があたると、影できるが、その影の明るさは一様でなく集光されて明るくなる部分も生じる。このような現象を表現する。この集光計算は屈折率を利用した極めて簡易的なものである。この効果は透明物体の影の範囲にしか生じない。値を小さくすると、集光部分が大きくなる。値に反比例して集光部分の大きさが変化する。正確な集光はフォトンマッピングを使用する。

図12.11-2は屈折によって透過光が集光される様子を擬似的に表している。

図12.11-2　擬似集光


●擬似集光の例（図12.11-2）



     sphere{0,1          // 左の球

       pigment{White*0.8 filter 1.0}

       interior{ ior 1.51}

       translate x*-1.2

     }



     sphere{0,1           // 右の球

       pigment{White*0.8 filter 1.0}

       interior{ ior 1.51 caustics 0.7}

       translate x*1.2

     }

12.11-3　分散（dispersion）

光の屈折率は波長により異なり、波長の短い方が長い方より屈折率が大きい。太陽光線は白色光線であり、可視光線の全波長が含まれている。このため、太陽光線はプリズムを通すと虹色に分かれる。このような現象を分散（分光）という。同様に太陽光線が空気中の水分で屈折し、分散することで虹が発生する。ここではフォトンマッピングを使用した例を示す。

図12.11-3a　分散なしの例


 intersection{

   box{<-1,-1,-1>,<1,1,1> rotate 45*x}

   plane{z, 0}

   material{

     texture{pigment{ color Clear } 

             finish { F_Glass1 } } 

     interior{I_Glass1 fade_color rgb 0.7}}

   photons {

     target   collect off  

     reflection on   refraction on }

  }

図12.11-3b　分散ありの例


 intersection{

   box{<-1,-1,-1>,<1,1,1> rotate 45*x}

   plane{z, 0}

   material{

     texture{pigment{ color Clear } 

             finish { F_Glass1 } } 

     interior{I_Glass1 fade_color rgb 0.7 

              dispersion 1.1

              dispersion_samples 20}}

   photons {

     target   collect off  

     reflection on   refraction on }

  }